"The Tower of the Elephant" by "Tor Andersson".

The story headline is "An Interactive Pulp Fiction".
The story genre is "Fantasy".
The release number is 0.

[ Bug fix for "Warning: grammar properties might not work correctly" ]
Include (- Array dictionary_push -> 400;  -) before the library.

[ Index map with EPS file. ]

The story description is "The shimmering shaft of the tower rose frostily in the stars. In the sunlight it shone so dazzlingly that few could bear its glare, and men said it was built of silver. It was round, a slim perfect cylinder, a hundred and fifty feet in height, and its rim glittered in the starlight with the great jewels which crusted it. The tower stood among the waving exotic trees of a garden raised high above the general level of the city. A high wall enclosed this garden, and outside the wall was a lower level, likewise enclosed by a wall. No lights shone forth; there seemed to be no windows in the tower -- at least not above the level of the inner wall. Only the gems high above sparkled frostily in the starlight."

Rule for printing the banner text: 
	say "[bold type][story title][roman type][line break]";
	say "[story headline] by [story author][end if][line break]";
	say "Based on the short story by Robert E. Howard[line break]";
	say "Release [release number] / Serial number [story serial number] / Inform 7 build [I7 version number][line break]";
	say "Type ABOUT if you have not played this game before." instead.

Include Plurality by Emily Short.
Include Conversation Rules by Eric Eve.

Use American dialect, no scoring and full-length room descriptions.

To give (n - a person) a proper name: (- give {n} proper; -).

To have the parser notice (n - an object):  (- PronounNotice({n}); -).

The time of day is 10:00 pm.

When play begins:
	change right hand status line to "".

Instead of asking someone about something:
	consider the unknown quizzing rule of the noun.
Instead of telling someone about something:
	consider the unknown informing rule of the noun.
Instead of answering someone that something:
	consider the unknown informing rule of the noun.

Quizzing someone about something is speech.
Informing someone about something is speech.

After saying hello to somebody:
	if the greeting type is explicit then consider the standard list suggested topics rule.

Understand "blow through [something held]" as blowing.

Section - Conan and the world

The Tower Gardens is a region.
The Tower Chambers is a region.

A weapon is a kind of thing.

The player carries a sword. The sword is a weapon.
The player wears some high strapped sandals.
The player wears a loin cloth.

Understand "high-strapped" as the high strapped sandals.
Understand "loin-cloth/loincloth" as the loin cloth.

Instead of taking off the loin cloth, say "No."
After taking off the sandals: say "You slip off your sandals."

Instead of examining yourself, say "A tall, strongly made youth. Your skin is brown from outland suns, your eyes blue and smoldering; a shock of tousled black hair crowns your broad forehead."

[Instead of taking something fixed in place: say "[The noun] is too bulky to lug around."]

Instead of praying: say "It is useless to call on Crom, because he is a gloomy, savage god, and he hates weaklings. But he gives a man courage at birth, and the will and might to kill his enemies, which, in your mind, is all any god should be expected to do."

Instead of swearing mildly: try praying.
Instead of swearing obscenely: try praying.

Section - Outer garden

The elephant tower is a backdrop. It is in the tower gardens.
"In the sunlight it shines so dazzlingly that few can bear its glare, and men say it is built of silver. It is round, a slim perfect cylinder, a hundred and fifty feet in height, and its rim glitters in the starlight with the great jewels which crust it."

[Instead of examining the elephant tower the first time, say "The tower stands among the waving exotic trees of a garden raised high above the general level of the city. A high wall encloses this garden, and outside the wall is a lower level, likewise enclosed by a wall."]

When play begins, say "'The secret of the Elephant Tower?' the Kothian had exclaimed. 'Why, any fool knows that Yara the priest dwells there with the great jewel men call the Elephant's Heart, that is the secret of his magic.'

The barbarian digested this for a space.

'I have seen this tower,' he said. 'It is set in a great garden above the level of the city, surrounded by high walls. I have seen no guards. The walls would be easy to climb. Why has not somebody stolen this secret gem?'"

After printing the banner text when not requesting the story file version:
say "[line break]The lurid lights and drunken revelry fall away behind you. You have discarded your torn tunic, and walk through the night naked except for a loin-cloth and high-strapped sandals. You move with the supple ease of a great tiger, steely muscles rippling under brown skin."

Temple District is a room.
"The temples glitter white in the starlight -- snowy marble pillars, golden domes and silver arches, shrines of Zamora's myriad strange gods. No watchmen pass here, for even the thieves of the Maul shun the temples, where strange dooms have been known to fall on violators. Shrubbery grows thick here, outside the lower wall. The shimmering shaft of the tower rises frostily in the stars to the east."

Some temples are here. They are scenery.
Understand "snowy", "marble", "pillars", "golden", "domes", "silver", "arches", "shrines" as the temples.
The description is "You do not trouble your head about these temples or their gods; you know that Zamora's religion, like all things of a civilized, long­settled people, is intricate and complex, and has lost most of the pristine essence in a maze of formulas and rituals. You had squatted for hours in the courtyards of the philosophers, listening to the arguments of theologians and teachers, and come away in a haze of bewilderment, sure of only one thing, and that, that they were all touched in the head."

Some shrubbery is here. It is scenery.
Understand "shrub", "shrubs", "bush", "bushes" as the shrubbery.

The lower wall is an open unopenable scenery door.
"It is high, but you could easily climb it."
Instead of climbing the lower wall, try entering the noun.

Instead of going west when in the temple district, say "Not so soon. The way in lies east, over the wall."

After going through the lower wall from the temple district:
	say "Leaping lightly you grasp the wall and swing yourself up to the top with one arm. Lying flat on the broad coping, you look down into the wide space between the walls. A quick look to right and left shows you no enemy. You cautiously lower yourself down on the inside[if the sword is carried] and draw your sword[end if], staring about.";
	continue the action.

Between the Walls is a room.
"[if player is not in the trimmed bushes]Standing unprotected in the naked starlight, you crouch low in the shadow of the curving wall. The starlight falls on the even sward and somewhere a fountain tinkles. Some carefully trimmed bushes grow near the inner wall[otherwise]You crouch low in the shadow of the bushes that grow near the inner wall. The starlight falls on the even sward and somewhere a fountain tinkles[end if]."

Instead of going north when in between the walls, say "That way lies the front gate; undoubtedly well guarded."
Instead of going south when in between the walls, say "The way in is east, over the wall." 

The higher wall is an open unopenable scenery door.
"The wall is covered in carvings of strange beasts, with a tail in front as well as behind."
Instead of climbing the higher wall, try entering the noun.

After going through the higher wall from between the walls:
	say "You leap up and climb over the wall, then carefully drop lightly to the sward inside the wall.";
	continue the action.

Some carefully trimmed bushes are here. They are scenery.
Understand "shrub", "shrubs", "shrubbery", "bush" as the trimmed bushes.

Section - Guard

The patrolling guard is a man.
"A guard is patrolling the gardens here."
The unknown quizzing rule is the default guard response rule.
The unknown informing rule is the default guard response rule.
Understand "man/soldier/watchman" as the patrolling guard.
The description is "A strongly built man in the silvered armor and crested helmet of the Zamorian royal guard."

When play begins, the guard enters in zero turns from now.

When the guard enters:
	move the patrolling guard to between the walls;
	if the player is in the temple district,
		say "You can hear the clink of steel. Within the garden some one is passing, who walks with a measured stride. So after all a guard does pace these gardens.";
	if the player is in between the walls,
		say "You can hear the clink of steel as a guard walks in from the north.";
	the guard leaves in zero turns from now.

Instead of listening when in the temple district and the patrolling guard is in between the walls:
	say "You wait, expecting to hear him pass again, on the next round, but silence rests over the mysterious gardens."

When the guard leaves:
	if the location is not between the walls begin;
		kill the guard;
		now the guard-corpse is strangled;
	end if.

To kill the guard:
	remove the patrolling guard from play;
	move the guard-corpse to between the walls;
	now the guard-corpse is seen.

Table of Guard Actions
action rule
Guard notices rule
Guard asks rule
Guard fidgets rule
Guard attacks rule

This is the guard notices rule: say "The guard must have heard you make some noise, for he wheels about to face you, and brings his spear to bear."
This is the guard asks rule: say "'Intruder! What do you in the garden of Yara?' the guard demands in a rough voice."
This is the guard fidgets rule: say "The guard nervously shifts his grip on the spear."
This is the guard attacks rule:
	say "The guard lunges out, piercing your chest with his spear. The searing pain is the last thing you feel.";
	end the game in death.

Every turn when the patrolling guard is in the location:
	repeat through the table of guard actions
	begin;
		follow the action rule entry;
		blank out the whole row;
		rule succeeds;
	end repeat.

This is the default guard response rule:
	say "'Is that so?' the guard replies, scornfully."

Instead of going when the guard is in the location:
	say "'Where do you think you are going, dog?' he asks.".

Instead of attacking the patrolling guard when the sword is carried:
	say "Your sword flashes frostily in the starlight. The man staggers and drops to his knees, before falling to the ground.";
	kill the guard.

Instead of attacking the patrolling guard:
	say "You lunge out with your fist, every ounce of tiger-like thews behind your blow. The sound of bone cracking as you break the man's skull echoes off the walls. He collapses to the ground, dead.";
	kill the guard.

The guard-corpse is an opaque, open, unopenable container. It is fixed in place.
The guard-corpse can be strangled or unstrangled. It is unstrangled.
"[if strangled]A form lies crumpled near the edges of the bushes[otherwise]A dead guard lies on the ground[end if]."
The printed name is "[if strangled]crumpled form[otherwise]dead guard[end if]".
The description is "You bend close to investigate. Even in the dim starlight, you see that [the guard-corpse] is a strongly built man in the silvered armor and crested helmet of the Zamorian royal guard[if strangled]. It takes but an instant's examination to show that he has been strangled. You glance about uneasily[end if]."
Understand "crumpled", "form", "guard", "corpse", "dead" or "body" as the guard-corpse.

A crested helmet is a wearable in the guard-corpse .
A silvered armor is a wearable and fixed in place in the guard-corpse .
A spear is in the guard-corpse. The spear is a weapon.

Section - The prince of thieves, himself

The thief is a man.
Understand "stranger" or "man" or "thief" or "fellow" or "prince of thieves" or "Taurus" or "Nemedian" as the thief.
The quizzing table is the table of thief answers.
The informing table is the table of thief remarks.
The unknown quizzing rule is the default thief response rule.
The unknown informing rule is the default thief response rule.
The description is "[The thief] is tall as you, and heavier; he is big-bellied and fat, but his every movement betokens a subtle dynamic magnetism, which is reflected in the keen eyes that glint vitally, even in the starlight. He is barefooted[if the thief carries the coil] and carries a coil of what looks like a thin, strong rope, knotted at regular intervals[end if]."

To name the thief:
	now the printed name of the thief is "Taurus";
	give the thief a proper name.

To decide whether it is safe for the thief to come out:
	if the thief is on-stage, decide no;
	if the thief-corpse is on-stage, decide no;
	if the guard is in the location, decide no;
	decide yes.

Instead of examining the trimmed bushes when it is safe for the thief to come out:
	introduce the thief.

Instead of going east from between the walls when it is safe for the thief to come out:
	introduce the thief.

To introduce the thief:
	move the thief to between the walls;
	now the thief is seen;
	have the parser notice the thief;
	say "You see a hint of motion through the shrubs. You [if the sword is carried]grip your sword and [end if]glide thither, making no more noise than a panther stealing through the night. You get a dim glimpse of a huge bulk close to the wall, and feel relief that it is at least human."

To kill the thief:
	remove the thief from play;
	move the thief-corpse to the location;
	now the thief-corpse is seen;
	now every thing that is had by the thief is in the thief-corpse.

Instead of  attacking the thief when a weapon is held:
	kill the thief;
	say "[The thief] stares at you in surprise when you slash his throat. His hands claw at his throat, blood gushing between his fingers, then he crumples to the ground."

Instead of attacking the thief:
	kill the thief;
	say "You lunge out, catching the thief's head between your powerful hands and twist. His knees buckle and he falls soundlessly to the ground with a broken neck."

The thief-corpse is an opaque, open, unopenable container.  It is fixed in place.
The printed name is "dead thief".
The initial appearance is "A dead thief lies on the ground."
The description is "You search the big-bellied body of [the thief] and find [list of things in the thief-corpse]."
Understand "thief" or "dead" or "body" or "Taurus" or "Nemedian" as the thief-corpse.

Section - The prince of thieves, conversation

This is the default thief response rule:
	show the next response from the table of thief misunderstandings.

Table of Thief Misunderstandings
response
"'Hmm?' [the thief] asks."
"'Your barbaric accent is too thick for me,' [the thief] chuckles."
"He does not understand what you are trying to say."
"'We waste time in this cursed discussion.'"
"'But come, in Bel's name! Are we to waste the night in discussion?'"

Table of Thief Introductory Remarks
response
"Then the fellow wheels quickly with a gasp that sounds like panic[if the sword is carried], makes the first motion of a forward plunge, hands clutching, but recoils as your blade catches the starlight[end if]."
"'You are no soldier,' hisses the stranger at last. 'You are a thief like myself.'"
"'Who are you?' he whispers."

Every turn when the player can see the thief:
	repeat through the table of thief introductory remarks
	begin;
		say "[response entry][paragraph break]";
		blank out the whole row;
		rule succeeds;
	end repeat.

Table of Thief Answers
subject		response rule		response table		suggest
thief		thief-self rule		a table-name		1
gem		thief-jewel rule		--			1
elephant tower	--			table of thief-tower	2
guard-corpse	thief-guard rule		--			1
coil		--			table of thief-coil	2
yara		--			table of thief-yara	3
lions		thief-lions rule		--			1
powder		--			table of thief-powder	3
lion-corpses	thief-lion-corpses rule	--			1

Table of Thief Remarks
subject		response rule		response table	suggest
yourself		thief-player rule		a table-name	1
lions		thief-lions rule		--		0
hook		thief-hook rule		--		0
ledge		thief-ledge rule		--		1

The thief-lets-go-node rules is a rulebook.
The thief-lets-go node is an unlimited conversation node.
The suggestions is "say yes". The node rule is the thief-lets-go-node rules.

This is the thief-self rule:
name the thief;
say "'And who are you?' you ask in a suspicious whisper.

'Taurus of Nemedia.'

You lower your sword.

'I've heard of you. Men call you a prince of thieves.'

A low laugh answers.[quiz the thief to -1]"

This is the thief-player rule:
say "'I am Conan, a Cimmerian,' you answer. 'I came seeking a way to steal Yara's jewel, that men call the Elephant's Heart.'

You sense the man's great belly shaking in laughter, but it is not derisive. 'By Bel, god of thieves!' hisses [the thief]. 'I had thought only myself had courage to attempt that poaching. These Zamorians call themselves thieves - bah! Conan, I like your grit. I never shared an adventure with anyone, but by Bel, we'll attempt this together if you're willing.'[inform yourself to -1][reveal gem][reveal elephant tower][convnode thief-lets-go node]";
repeat through the table of thief introductory remarks begin; blank out the whole row; end repeat.

This is the thief-jewel rule:
say "'Then you are after the gem, too?'

'What else? I've had my plans laid for months, but you, I think, have acted on sudden impulse, my friend.'"

This is the thief-guard rule:
if the guard-corpse is strangled,
say "'You killed the soldier?'

'Of course. I slid over the wall when he was on the other side of the garden. I hid in the bushes; he heard me, or thought he heard something. When he came blundering over, it was no trick at all to get behind him and suddenly grip his neck and choke out his fool's life. He was like most men, half blind in the dark. A good thief should have eyes like a cat.'

'You made one mistake. You should have dragged the body into the bushes.'

'Said the novice to the master of the art. ";
otherwise say "'Help me drag the body into the bushes.'

'No. ";
say "They will not change the guard until past midnight. Should any come searching for him now, and find his body, they would flee at once to Yara, bellowing the news, and give us time to escape. Were they not to find it, they'd go beating up the bushes and catch us like rats in a trap.'".

Table of thief-tower
response
 "'What of the soldiers in the lower part of the tower?'

'Old Yara dwells in the chambers above. By that route we will come - and go, I hope. Never mind asking me how. I have arranged a way. We'll steal down through the top of the tower and strangle old Yara before he can cast any of his accursed spells on us.'[reveal Yara]"
"'I see no light,' you mutter.

'There are cleverly constructed doors and windows,' answers Taurus, 'but they are closed. The soldiers breathe air that comes from above.'"

Table of thief-coil
response
"'Will the rope bear my weight?' you grunt.

'It will bear thrice my own,' answers [the thief]. 'It was woven from the tresses of dead women, which I took from their tombs at midnight, and steeped in the deadly wine of the upas tree, to give it strength.'"

Table of thief-yara
response
"'Men say that Yara comes not often from his tower of magic, and always to work evil on some man or some nation. The king of Zamora fears him more than he fears death, and keeps himself drunk all the time because that fear is more than he could endure sober,' he tells you."
"'Once, Yara laughed in the face of a hostile prince, and held up a glowing, evil gem before him, and rays shot blindingly from that unholy jewel, to envelop the prince, who screamed and fell down, and shrank to a withered blackened lump that changed to a black spider which scampered wildly about the chamber until Yara set his heel upon it,' he recounts."
"'Will he not do the same, should he find us attempting to poach his treasure?'

'It's the chance of being turned into a spider or a toad, against the wealth and power of the world. All good thieves must know how to take risks.'"

After speech in the presence of the thief when the location is between the walls for the fourth time:
say "'So. Now attend. We waste time in this cursed discussion. There are no guards in the inner garden - human guards, I mean, though there are sentinels even more deadly. It was their presence which baffied me for so long, but I finally discovered a way to circumvent them,' [the thief] says.";
continue the action.

A thief-lets-go-node rule when saying yes:
	say "'I'll go as far as any man,' you say.

'Then follow me.'";
	silently try saying goodbye to the thief;
	rule succeeds.

A thief-lets-go-node rule when saying no:
	say "'I do not need any mans help,' you say.

The thief smiles at you. 'Follow me.'";
	silently try saying goodbye to the thief;
	rule succeeds.

After saying goodbye to the thief when the location is between the walls:
	say "Turning, [the thief] leaps up, catches the wall and draws himself up. The man's suppleness is amazing, considering his bulk; he seems almost to glide up over the edge of the coping.[convnode null node]";
	now the thief is in the Garden.

This is the thief-lions rule:
if the lions are in the location, say "'Lions!' you mutter.

'Aye. By day they are kept in subterranean caverns below the tower. That's why there are no guards in this garden.'

You count the eyes rapidly.

'Five in sight; maybe more back in the bushes. They'll charge in a moment--'[line break]";
otherwise follow the default thief response rule;
say quiz the lions to -1;
say inform the lions to -1.

This is the thief-lion-corpses rule:
say "'All things are strange in this garden,' [the thief] says. 'The lions strike silently -- and so do other deaths. But come -- little sound was made in that slaying, but the soldiers might have heard, if they are not asleep or drunk.'"

Table of thief-powder
response
"'What is that mist?' you ask uneasily.

'Death!' hisses the Nemedian. 'If a wind springs up and blows it back upon us, we must flee over the wall. But no, the wind is still, and now it is dissipating. Wait until it vanishes entirely. To breathe it is death.'"
"'They died without a sound!' you mutter. 'Taurus, what was that powder?'

'It was made from the black lotus, whose blossoms wave in the lost jungles of Khitai, where only the yellow-skulled priests of Yun dwell. Those blossoms strike dead any who smell of them.'"
"'Why can you not slay the soldiers in the tower in the same way?' you ask.

'Because that was all the powder I possessed. The obtaining of it was a feat which in itself was enough to make me famous among the thieves of the world. I stole it out of a caravan bound for Stygia, and I lifted it, in its cloth-of-gold bag, out of the coils of the great serpent which guarded it, without awaking him.'"

This is the thief-ledge rule:
say "'There is a fabulous fortune here,' you whisper; but the Nemedian answers impatiently, 'Come on! If we secure the Heart, these and all other things shall be ours.'"

This is the thief-hook rule:
say "'Luck was with us again,' he mutters. 'One would think that our combined weight would have torn that stone out. Follow me; the real risks of the venture begin now. We are in the serpent's lair, and we know not where he lies hidden.'"

Section - Lions

Garden is a room.
"The garden is a vague pool of shadows where feathery bushes and low spreading trees wave darkly in the starlight. Beyond them, to the east, you see the smooth silver shaft of the tower. A footpath leads north."

Some living lions are animals in the garden.
Understand "eyes" or "sparks" as lions.
The initial appearance is "[if garden is unvisited]You catch a subtle scent that make the short hairs on your neck instinctively bristle as a hunting dog bristles at the scent of an ancient enemy. [end if]Two great eyes blaze from the waving shadows, and behind them other sparks of fire glint in the darkness."
The description is "Lions! Low rumblings rise from the shadows and the blazing eyes move forward. You can sense the great slavering jaws, the tufted tails lashing tawny sides."

Instead of going when the lions are in the location:
	say "As you turn your back to the shadows, a fleeting glimpse shows you a giant tawny shape, rearing upright against the stars, towering over you for the death-stroke.";
	end the game in death.

Instead of attacking the lions:
	say "As you draw near the shapes, they draw back and circle around you, warily watching every movement."

Some lion-corpses are fixed in place things.
The printed name is "dead lions".
Understand "tawny" or "shapes" or "dead" or "lion" or "lions" or "corpse" or "corpses" as the lion-corpses.
The description is "You kneel beside the great forms, assuring yourself that they are indeed beyond power of harm."
The initial appearance is "Stretched out in the shadows lie five great tawny shapes, the fire of their grim eyes dimmed for ever. A sweetish cloying scent lingers in the atmosphere."

The thief carries a leather pouch.
The leather pouch is a closed and openable container.
The description is "An ordinary leather pouch, the size of a child's fist."

The thief carries a copper tube.
The copper tube is an open, unopenable container.
The description is "A hollow copper tube, half an inch thick."

The powder is in the leather pouch.
The indefinite article of the powder is "some".
Understand "black" or "lotus" or "yellow" or "yellowish" as the powder.
The description of the powder is "A yellowish powder."

The yellow-green mist is scenery.
Understand "yellow" or "green" or "cloud" as the mist.
The description of the mist is "The thick cloud hides the shrubbery."

After going to the garden when the thief is in the garden:
	the thief whispers keep behind me in zero turns from now;
	continue the action.

When the thief whispers keep behind me:
	if the thief is visible, say "'Keep behind me, as you value your life,' [the thief] whispers.";
	the thief takes the copper tube in zero turns from now.

When the thief takes the copper tube:
	if the thief is visible, say "[The thief] takes what looks like a copper tube from his girdle, his whole attitude is of tense expectancy, and his gaze fixed on the shadowy mass of shrubbery.";
	the thief blows the powder in zero turns from now.

Instead of inserting something that is not the powder into the tube, say "[The noun] does not fit inside the copper tube."

Instead of smelling, tasting, drinking or eating the powder:
	say "The last thing you remember is a sweetish cloying scent.";
	end the game in death.

Instead of blowing the tube:
	say "You bring the tube to your lips and blow forcefully. Axir whistles as it shoots from the other end of the tube."

Instead of blowing the tube when the powder is in the tube:
	say "You bring the tube to your lips and blow forcefully. A long jet of yellowish powder shoots from the other end of the tube and billows out instantly in a thick green-yellow cloud.";
	remove the powder from play;
	now the mist is in the location; now the mist is seen;
	if the location is not the garden, the mist blows back in zero turns from now;
	otherwise the mist settles in one turn from now.

When the thief blows the powder:
	if the thief is visible, say "'Be silent!' [the thief] hisses, and moves out from the wall, cautiously as if treading on razors. Then he brings the mouth of the tube to his lips and blows powerfully. A long jet of yellowish powder shoots from the other end of the tube and billows out instantly in a thick green-yellow cloud.";
	remove the powder from play;
	now the mist is in the garden; now the powder is seen; now the mist is seen;
	the mist settles in zero turns from now.

Instead of going when the mist is in the location:
	say "You walk into the yellowish mist. The last thing you remember is a sweet cloying smell.";
	end the game in death.

When the mist blows back:
	say "A wind springs up and blows the yellow cloud back upon you. The last thing you remember is a sweet cloying smell.";
	end the game in death.

When the mist settles:
	if the mist is visible, say "The cloud settles over the shrubbery, blotting out the glaring eyes.";
	remove the lions from play;
	now the lion-corpses are in the location; now the lion-corpses are seen;
	the mist dissipates in zero turns from now.

When the mist dissipates:
	if the mist is visible, say "Presently only yellowish shreds hang ghostily in the air; then they are gone.";
	remove the mist from play;
	[ first topic makes no sense when the mist is not visible; this advances the index to skip it ]
	choose row with a tabname of table of thief-powder in the table of table types;
	if the index entry is 0 begin;
		change the index entry to 1;
		choose row with a response table of table of thief-powder in the table of thief answers;
		change the suggest entry to the suggest entry minus one;
	end if;
	if the thief is in the garden, the thief walks to the foot of the tower in one turn from now.

When the thief walks to the foot of the tower:
	if the thief is in the garden begin;
		try the thief trying going east;
		the thief unwinds the coil in one turns from now;
	end if.

Report the thief trying going east from the garden:
	say "The thief works his way eastward through the shrubbery to the gleaming foot of the 
tower." instead.

Fountain is a room.

Section - Scaling the Tower

Foot of the Tower is a room.
"The lower part of the tower seems much like that portion visible from outside the garden -- a perfect, gleaming cylinder, with no apparent openings. Only the gems high above sparkle frostily in the starlight[if the end of the rope is in the foot of the tower].

A knotted cord hangs about a foot from the side of the tower[end if]."

Instead of listening when in the foot of the tower:
	say "You lay your ear to the smooth wall and listen, but can hear nothing. Evidently the soldiers within do not suspect the presence of intruders."

Instead of going up when in the foot of the tower and the end of the rope is not in the location:
	say "You can't go that way."

The thief carries a thin strong knotted coil.
The description of the coil is "A knotted cord, on one end of which is a strong steel hook."
Understand "rope" or "cord" as the coil.

When the thief unwinds the coil:
	if the thief is in the foot of the tower begin;
		if the thief is visible, say "With a motion enjoining silence, [the thief] unwinds his knotted cord, on one end of which is a strong steel hook.";
		the thief throws the coil in zero turns from now;
	end if.

When the thief throws the coil:
	if the thief is in the foot of the tower begin;
		if the thief is visible, say "[The thief] throws the line with a smooth ripping motion of his mighty arm. The hook curves upward and inward in a peculiar manner, and vanishes over the jeweled rim. It apparently caught firmly, for cautious jerking and then hard pulling does not result in any slipping or giving.";
		remove the coil from play;
		now the end of the rope is in the Foot of the Tower;
		now the hook is in the Balcony;
		the thief climbs the coil in zero turns from now;
	end if.

When the thief climbs the coil:
	if the thief is in the foot of the tower begin;
		if the thief is visible, say "'Luck the first cast,' murmurs [the thief]. 'We must climb this cord -- little need to ask a Cimmerian if he can.' [The thief] grips the rope and crooks a knee about it, begins the ascent; he goes up like a cat, belying the apparent clumsiness of his bulk.";
		now the thief is in the Balcony;
	end if.

Instead of throwing the coil at the elephant tower when in foot of the tower:
	say "You throw the line with a smooth ripping motion. The hook curves upward and inward in a peculiar manner, and vanishes over the jeweled rim.";
	remove the coil from play;
	now the end of the rope is in the Foot of the Tower;
	now the hook is in the Balcony.

The end of the rope is scenery.
Understand "knotted" or  "coil" or "cord" as the end of the rope.

Instead of pulling the end of the rope:
	say "It apparently caught firmly, for cautious jerking and then hard pulling does not result in any slipping or giving."

Instead of taking the end of the rope:
	try pulling the end of the rope.

Instead of climbing the end of the rope: try going up.
Instead of climbing the middle of the rope: try going up.
Instead of climbing the hook: try going down.

Tower Shaft is a room.
"The cord sways and turns on itself, but you are not hindered; you have made more difficult climbs before. The jeweled rim glitters high above, jutting out from the perpendicular of the wall, so that the cord hangs perhaps a foot from the side of the tower -- a fact which adds greatly to the ease of the climb."

Before going up from the tower shaft:
	say "Up and up you go, silently, the lights of the city spreading out further and further to sight as you climb, the stars above more and more dimmed by the glitter of the jewels along the rim."

Tower Rim is a room.
"You pause a moment on the very edge, fascinated by the great frosty jewels whose gleams dazzle your eyes -- ­diamonds, rubies, emeralds, sapphires, turquoises, moonstones, set thick as stars in the shimmering silver. At a distance their different gleams seemed to merge into a pulsing white glare; but now, at close range, they shimmer with a million rainbow tints and lights."

Before going up from the tower rim:
	say "You climb over the sparkling rim."

The middle of the rope is a backdrop.
The middle of the rope is in the Tower Shaft and the Tower Rim.
Understand "knotted" or "coil" or "cord" as the middle of the rope.

Instead of taking the middle of the rope, say "You're hanging from it."

Section - Tower

Balcony is a room.
"The level of the tower's top is some feet below the gemmed ledge. It is flat, composed of some dark blue substance, set with gold that catches the starlight, so that the whole looks like a wide sapphire flecked with shining gold-dust. There seems to be a sort of chamber, built upon the roof. It is of the same silvery material as the walls of the tower, adorned with designs worked in smaller gems; its single door is of gold, its surface cut in scales, and crusted with jewels that gleam like ice."

The hook is scenery.
Understand "knotted" or "coil" or "rope" as the hook.
The description is "Where the hook caught -- a fraction of an inch of the point had sunk under a great blazing jewel on the inner side of the rim.[inform hook to 1]"

Instead of taking the hook, say "The hook is firmly embedded in the wall."

The gemmed ledge is a backdrop and in the balcony and the tower rim.
Understand "diamonds/rubies/emeralds/sapphires/turquoises/moonstones" as the gemmed ledge.
The description is "Diamonds, rubies, emeralds, sapphires, turquoises, moonstones, set thick as stars in the shimmering silver."

The roof top chamber is scenery in the balcony.

The gold door is a door and scenery.
Understand "jewels" or "scales" as the gold door.

Instead of going inside when in the balcony:
	try entering the gold door.

Instead of going down when in the balcony and the hook is not in the location:
	say "You can't go that way."

Instead of opening the gold door in the presence of the thief:
	the thief enters the gold door.

After saying goodbye to the thief when the location is between the walls:
	the thief enters the gold door;
	continue the action.

To the thief enters the gold door:
	say "'Before we cut off our last retreat,' Taurus hisses, 'go you to the rim and look over on all sides; if you see any soldiers moving in the gardens, or anything suspicious, return and tell me. I will await you within this chamber.'x

The Nemedian slips inside the door and draws it shut behind him.";
	now the thief is in the Treasure Chamber;
	the thief exits the gold door in one turn from now.

When the thief exits the gold door:
	say "Suddenly from within the chamber there sounds a strangled cry.";
	if the player is in the balcony, say "[line break]The gleaming door swings open and [the thief] stands framed in the cold blaze behind him. He sways and his lips part, but only a dry rattle bursts from his throat. Catching at the golden door for the support, he lurches out upon the roof, then falls headlong, clutching at his throat.

The door swings to behind him. You saw nothing in the room behind the stricken Nemedian, in the brief instant the door was partly open -- unless it was not a trick of the light which made it seem as if a shadow darted across the gleaming floor.[line break]";
	remove the thief from play;
	now the thief-corpse is in the balcony;
	the thief expires in zero turns from now.

When the thief expires:
	if the player is in the balcony, say "The Nemedian stares up with dilated, glazing eyes, that somehow hold a terrible bewilderment. His hands claw at his throat, his lips slobber and gurgle; then suddenly he stiffens."

Instead of examining the thief-corpse when in the balcony:
	say "Gingerly you run his hands over the man's half-naked body, seeking a wound. But the only marks of violence are between his shoulders, high up near the base of his bull-neck -- three small wounds, which look as if three nails have been driven deep in the flesh and withdrawn. The edges of these wounds are black, and a faint smell as of putrefaction is evident."

The garden view is scenery in the balcony.
The description is "You see no movement in the vaguely waving sea of leaves below."

Section - Giant Spider

Treasure Chamber is a room.
"The chamber lies empty, bathed in the cold, pulsing glow of the myriad jewels. [if unvisited]In the very center of the ceiling you idly note a curious design -- a black eight-sided pattern, in the center of which four gems glitter with a red flame unlike the white blaze of the other jewels. [end if]Across the room, there is a stairway leading down. There are no chairs or tables in the chamber, only three or four silken couches."

The silken couches are enterable, scenery and here.
Understand "couch" as the couches.
The description is "Three or four silken couches, embroidered with gold and worked in strange serpentine designs."

Some silver-bound mahogany chests are here.
Understand "chest" or "jewel" as the chests.
The initial appearance is "Several silver-bound mahogany chests are here."
The description is "Some are sealed with heavy golden locks; others lie open, their carven lids thrown back, revealing heaps of jewels in a careless riot of splendor."

Instead of exiting when in the treasure chamber:
	try entering the gold door.

The gigantic black spider is an animal.
Understand "hairy" or "monster" or "creature" or "horror" as the spider.
The description is "It is as large as a pig, and its eight thick hairy legs drive its ogreish body over the floor at headlong pace; its four evilly gleaming eyes shine with a horrible intelligence, and its fangs drip venom that you know, from the burning of your shoulder where only a few drops had splashed as the thing struck and missed, is laden with swift death."

The spider-corpse is fixed in place.
The printed name is "dead spider".
Understand "gigantic" or "black" or "spider" or "crushed" or "dead" or "body" as the spider-corpse.
Understand "hairy" or "monster" or "creature" or "horror" as the spider-corpse.
The initial appearance is "A crushed black body lies among the jewels.".
The description is "The hairy legs move aimlessly, the dying eyes glitter redly among twinkling gems."

Instead of doing anything when in the treasure chamber for the first time:
	now the spider is in the treasure chamber.

Table of Spider Moves
response
"A flying shadow that sweeps across the gleaming floor is your only warning, and your instinctive sidelong leap all that saves your life. You have a flashing glimpse of a hairy black horror that swings past with a clashing of frothing fangs, and something splashes on your bare shoulder that burns like drops of liquid hell-fire."
"You see the horror strike the floor, wheel and scuttle toward you with appalling speed -- a gigantic black spider, such as men see only in nightmare dreams."
"You leap high, and the spider passes beneath you, wheels and charges back."
"This time you evade its rush with a sidewise leap, and strike back like a cat."
"Your sword severs one of the hairy legs."
"You barely save yourself as the monstrosity swerves, fangs clicking fiendishly."
"Turning, the creature scuttles across the crystal floor and runs up the wall to the ceiling, where it crouches for an instant, glaring down with its fiendish red eyes."
"Without warning the spider launches itself through space, trailing a strand of slimy grayish stuff."
"You step back to avoid the hurtling body -- then duck frantically, just in time to escape being snared by the flying web-rope."
"The spider races across the chamber floor, the gray rope waving out behind it."
"You leap high, clearing a couch -- with a quick wheel the fiend runs up the wall, and the strand, leaping off the floor like a live thing, whips about your ankle."
"You catch yourself on your hands as you fall, jerking frantically at the web which holds you like a pliant vise, or the coil of a python."
"The hairy devil is racing down the wall to complete its capture."

The sticky strand is fixed in place.
The initial appearance is "Gray strands lie in coils on the floor; they are looped along the walls; they overlay silken couches, and hang in dusky festoons from the jeweled ceiling."
The description is "Strands of slimy grayish stuff."

Instead of attacking or cutting the sticky strand when the player carries the sword and the spider is in the location:
	say "You try to cut it with your sword; the stuff clings to the blade and before you can shake it loose, the fiend is sinking its fangs in to your back.";
	end the game in death.

Instead of attacking the spider:
	show the next response from the table of spider moves.

Every turn when the spider is in the location:
	show the next response from the table of spider moves;
	choose row with a tabname of table of spider moves in the table of table types;
	if the index entry >= 8, now the sticky strand is in the treasure chamber;
	if the index entry >= 12 begin;
		end the game in death;
	end if.

Instead of going when the spider is in the location:
	say "You spring toward the door, but the monster is quicker, and a sticky strand cast across the door make you a prisoner.";
	now the sticky strand is in the treasure chamber.

Instead of throwing something at the spider:
	say "You hurl [the noun] with all your strength, but it bounces harmlessly off the spider and falls to the floor.";
	now the noun is in the location.

Instead of throwing a weapon at the spider:
	say "You hurl [the noun] with all your strength. Full in the midst of the branching black legs the missile strikes, punching through its shell. Blood and greenish slime spatters, and the mass falls with [the noun] to the floor.";
	remove the spider from play;
	now the noun is in the location;
	now the spider-corpse is in the location.

Instead of throwing the chests at the spider:
	say "You catch a jewel chest and hurl it with all your strength. It is not a move the spider was expecting. Full in the midst of the branching black legs the massive missile strikes, smashing against the wall with a muffled sickening crunch. Blood and greenish slime spatters, and the shattered mass falls with the burst gem-chest to the floor.";
	remove the spider from play;
	now the chests are in the location;
	now the spider-corpse is in the location.

Instead of taking the spider-corpse:
	say "The shattered mass of blood, hair and slime is worthless."

Section - Stairs and Chambers

Silver Stairway is a room.
"A flight of silver steps lead up and down, dimly lighted by what means you can not ascertain. An ivory door, set with blood stones [if ivory door is open]stands open[otherwise]is here[end if]. Thin wisps of smoke drift lazily from [if ivory door is closed]beneath the door[otherwise]the open door[end if], bearing a curious exotic odor."

Some thin wisps of smoke are scenery in the silver stairway.
Instead of smelling or examining the thin wisps of smoke, say "Exotic incense."
Instead of taking the thin wisps of smoke, say "The smoke is intangible."

The ivory door is a door, closed and scenery.
The description is "An ivory door, set with blood stones."

Report opening the ivory door when in the silver stairway:
	say "Cautiously you press against the ivory door. It swings silently inward." instead.

Instead of going inside when in the silver stairway, try entering the ivory door.

Ivory Chamber is a room.
"A large chamber with a domed golden ceiling, walls of green jade, floor of ivory, partly covered by thick rugs. Smoke and exotic incense floats up from a brazier on a golden tripod."

The green jade walls, ivory floor, thick rugs, golden tripod and brazier are scenery in the Ivory Chamber. Understand "incense/smoke" as the brazier.

Yag-kosha is a man and in the ivory chamber.
Yag-kosha can be sleeping or awake. Yag-kosha is sleeping.
Understand "idol/elephant/creature/monster/man" as Yag-kosha.
The initial appearance is "Behind it sits [if Yag-kosha is sleeping]an idol[otherwise]a living idol[end if] on a marble couch."
The description is "[if Yag-kosha is sleeping]The image[otherwise]He[end if] has the body of a man, naked, and green in color; but the head is one of nightmare and madness. Too large for the human body, it has no attributes of humanity. You stare at the wide flaring ears, the curling proboscis, on either side of which stand white tusks tipped with round golden balls[if Yag-kosha is sleeping]. The eyes are closed, as if in sleep[end if]."

Instead of doing something other than looking or examining when Yag-kosha is in the location and Yag-kosha is sleeping:
	say "As you come forward, your eyes fixed on the motionless idol, the eyes of the thing open suddenly! You freeze in your tracks. It is no image -- it is a living thing, and you are trapped in its chamber!";
	now Yag-kosha is awake.


Instead of going from the ivory chamber when Yag-kosha is in the location:
	say "You begin to back silently toward the door; but the creature hears."
[	try saying hello to Yag-kosha.]

After saying hello to Yag-kosha:
	say "The sensitive trunk stretches toward you, and the being speaks, in a strange, stammering voice that never changes its key or timbre. Those jaws were never built or intended for human speech.

'Who is here? Have you come to torture me again, Yara? Will you never be done? Oh, Yag-kosha, is there no end to agony?'"

Instead of exiting when in the ivory chamber, try entering the ivory door.

Section - The End Game

Dark Stairway is a room.
"Below the silver stair winds down to vanish in the dimness, and up that shadowy well no sound floats; you have an eery feeling that you are alone in a tower occupied only by ghosts and phantoms. An ebony door, in the center of which is a grinning silver skull, [if ebony door is open]stands open[otherwise]is here[end if]."

Ebony Chamber is a room.

The ebony door is a door, closed and scenery.

Instead of going inside when in the dark stairway, try entering the ebony door.
Instead of exiting when in the ebony chamber, try entering the ebony door.

Watch Chamber is a room.
"A large chamber at the foot of the gleaming stairs. You have come into the room of the soldiers. You see the glitter of their silver corselets, the sheen of their jeweled sword-hilts. They sit slumped at the banquet board, their dusky plumes waving somberly above their drooping helmeted heads; they lie among their dice and fallen goblets on the wine-stained lapis-lazuli floor. And you know that they are dead. And a silver door stands open, framed in the whiteness of dawn."

Instead of exiting when in the watch chamber, try entering the silver door.

Instead of going through the silver door from the watch chamber:
	say "Into the waving green gardens you come, and as the dawn wind blows with the cool fragrance of luxuriant growths, you start like a man waking from a dream. You turn back uncertainly, to stare at the cryptic tower you have just left. Were you bewitched and enchanted? Have you dreamed all that have seemed to have passed? As you look you saw the gleaming tower sway against the crimson dawn, its jewel-crusted rim sparkling in the growing light, and crash into shining shards.";
	end the game in victory.

Section - Mapping

The silver door is a door and scenery.

The lower wall is east from the temple district and west from between the walls.
The higher wall is east from between the walls and west from the garden.

The fountain is north from the garden.
The foot of the tower is east from the garden.
The tower shaft is up from the foot of the tower.
The tower rim is up from the tower shaft.
The balcony is up from the tower rim.

The dark stairway is up from the watch chamber.
The silver stairway is up from the dark stairway.
The treasure chamber is up from the silver stairway.

The gold door is north from the balcony and south from the treasure chamber.
The ivory door is west from the silver stairway and east from the ivory chamber.
The ebony door is east from the dark stairway and west from the ebony chamber.
The silver door is east from the fountain and west from the watch chamber.

The temple district, between the walls, garden, fountain, foot of the tower, tower shaft, tower rim and balcony are in the tower gardens.

The watch chamber, dark stairway, silver stairway, treasure chamber, ivory chamber, ebony chamber are in the tower chambers.

Section - Actors and props


Yara is a man in the ebony chamber.
Some watchmen are men in the watch chamber.

A gem is a thing in the ivory chamber.


Section - Conversation Tables

Table of Table Types (continued)
tabname			index	tabtype
table of thief misunderstandings	0	shuffled-list
table of thief-coil		0	stop-list
table of thief-yara		0	stop-list
table of thief-tower		0	stop-list
table of thief-powder		0	stop-list
table of spider moves		0	stop-list

Section - Inform 6 Banner Hackery

To say story serial number: (- SerialNumber(); -).
To say I7 version number: (- I7BuildVersion(); -).

Include (-
[ SerialNumber i;
#Ifdef TARGET_ZCODE ;
	for (i=0 : i < 6 : i++) print (char) 18->i;
#Ifnot ;
	for (i=0 : i < 6 : i++) print (char) $36->i;
#Endif ;
];

[ I7BuildVersion;
	print (string) NI_BUILD_COUNT, " ";
	print "(I6/v"; inversion;
	print " lib ", (string) LibRelease, ") ";
#ifdef STRICT_MODE;
	print "S";
#endif;
#ifdef INFIX;
	print "X";
#ifnot;
#ifdef DEBUG;
	print "D";
#endif;
];
-)